lumberjacking script

Share your guides, how-tos, FAQs, and so forth. This is not for support -- post questions in General Discussion.
Post Reply
User avatar
gloss
Posts: 32
Location: Lithuania

lumberjacking script

Post by gloss »

looking for good script for luberjacking
User avatar
kakel_anders
Posts: 361

Re: lumberjacking script

Post by kakel_anders »

Good script i used and did some adaptions on, just small things really.
Will shout guards, will cut to boards on the go.
Can be optimized alot more tbh..

1. Create an Organizer named "Lumberjack" with all gems, boards extra crap and all that comes from lumberjacking.
2. You need 3 books full of runes on the tile EAST of a tree.
Use this short macro while marking to see if it will work!

Code: Select all

useobject 'Axe'
pause 1500
targettileoffset -1 0 0
3. Create another runebook named "Home" with a default rune to a destination where you can reach your secured chest.
4. Adjust weightlimit in script.
5. Profit

Code: Select all

//Author: Experience
//Title: Recalling Lumberjack
//Description: Recalling Lumberjack. Must have a Double Axe.
//You will need a book with the default rune marked right next to your wood storage.
//All Books must have 16 runes to run properly!!
//To add more books simply add 'Wood4' findalias and to pushlist
removelist 'Runes'
removelist 'WoodBook'
@clearjournal
if not @findalias 'Wood Storage'
  promptalias 'Wood Storage'
endif
if not @findobject 'Wood1r'
  promptalias 'Wood1r'
endif
if not @findobject 'Wood2r'
  promptalias 'Wood2r'
endif
if not @findobject 'Wood3r'
  promptalias 'Wood3r'
endif
if not @findobject 'HomeWoodr'
  promptalias 'HomeWoodr'
endif
if not listexists 'WoodBook'
  createlist 'WoodBook'
endif
if list 'WoodBook' == 0
  pushlist 'WoodBook' 'Wood1r'
  pushlist 'WoodBook' 'Wood2r'
  pushlist 'WoodBook' 'Wood3r'
endif
if @findtype '0xf4b' 'any' 'backpack' 'any' '2' or findlayer 'self' '2'
  setalias 'Axe' 'found'
  headmsg 'Axe Found'
else
  headmsg 'No Axe Found'
  pause 800
endif
if not listexists 'Runes'
  createlist 'Runes'
endif
if list 'Runes' == 0
  pushlist 'Runes' 5
  pushlist 'Runes' 11
  pushlist 'Runes' 17
  pushlist 'Runes' 23
  pushlist 'Runes' 29
  pushlist 'Runes' 35
  pushlist 'Runes' 41
  pushlist 'Runes' 47
  pushlist 'Runes' 53
  pushlist 'Runes' 59
  pushlist 'Runes' 65
  pushlist 'Runes' 71
  pushlist 'Runes' 77
  pushlist 'Runes' 83
  pushlist 'Runes' 89
  pushlist 'Runes' 95
endif
for 0 to WoodBook
  for 0 to 'Runes'
    pause 500
    @clearjournal
    pause 500
    useobject WoodBook[]
    waitforgump 0x554b87f3 5000
    replygump 0x554b87f3 Runes[]
    pause 4000
    if injournal 'blocked' 'system'
      @clearjournal
      replay
    endif
    //tells you which rune you are on, see runelist above
    sysmsg 'Rune' 33
    sysmsg Runes[] 33
    pause 2500
    while not @injournal 'not enough wood here' 'system'
      if not @findlayer 'self' '2'
        equipitem 'Axe' '2'
        pause 1000
      endif
      //use axe to WESTERN tile until specified weight is reached
      pause 500
      useobject 'Axe'
      pause 1500
      targettileoffset -1 0 0
      pause 1000
      msg 'Guards'
      pause 1000
      if @findtype '0x1bdd' 'any' 'backpack' 'any' 'any'
        @setalias 'Logs' 'Found'
        useobject 'Axe'
        autotargetobject 'Logs'
        pause 1000
      endif
      // once weight is reached go home, if getting overweight, lower it
      if weight > '320'
        useobject 'HomeWoodr'
        waitforgump 0x554b87f3 5000
        replygump 0x554b87f3 5
        pause 2500
        //put up Wood
        //while @findtype '0x1bdd' 'any' 'backpack' 'any' '2'
        //  moveitem 'found' 'Wood Storage'
        //  pause 1000
        // Organizer approach //
        organizer 'Lumberjack'
        while organizing
        endwhile
        //endwhile
        //recall back to where you were
        useobject WoodBook[]
        waitforgump 0x554b87f3 5000
        replygump 0x554b87f3 Runes[]
        pause 2000
      endif
    endwhile
  endfor
  poplist 'Runes' 'front'
endfor
//recall home so Wood container is found
pause 1000
cast 'recall'
autotargetobject 'HomeWood'
pause 4000
poplist 'WoodBook' 'front'
"Commander #1638" on Discord

"Don't say anything bad about someone until you've walked a mile in his shoes. That way, when you say something bad, you're a mile away, and you've got his shoes." - Jack Handey - Deep Thoughts (SNL)
User avatar
gloss
Posts: 32
Location: Lithuania

Re: lumberjacking script

Post by gloss »

it works but its rllly slow :) if anyone can share another one
User avatar
kakel_anders
Posts: 361

Re: lumberjacking script

Post by kakel_anders »

Yes it's slow.. but i added a bit to the pauses cause it was hanging up on me from time to time :)
If you spend 2 minutes getting to know the script by say.. reading it? You could probably adjust that yourself quite easily.
"Commander #1638" on Discord

"Don't say anything bad about someone until you've walked a mile in his shoes. That way, when you say something bad, you're a mile away, and you've got his shoes." - Jack Handey - Deep Thoughts (SNL)
Post Reply